Pro Tips: come rimuovere files .DMG e immagini disco in un colpo solo

Come molti di voi avranno notato, anche lo staff di iSpazioMac si sta concedendo un pò di vacanza…ma non abbiamo di certo intenzione di lasciarvi senza letture interessanti fino a Settembre! Ecco dunque che oggi vi proponiamo un trucchetto molto intelligente per semplificare un passaggio che avviene molto spesso nel nostro utilizzo quotidiano di OS X, di cui sicuramente non avrete mai sentito parlare.

Il titolo potrebbe aver confuso i Mac users meno esperti, per cui spieghiamoci subito. Quasi tutte le applicazioni che scarichiamo da internet al di fuori del Mac App Store ci vengono proposte all’interno di un pacchetto di estensione .dmg. Aprire il pacchetto è diverso dall’aprire una cartella o estrarre un file compresso: ne uscirà fuori un disco virtuale (una immagine disco) che conterrà i files necessari all’installazione.

Come funziona per rimuovere le tracce di questi pacchetti, una volta installata l’applicazione? Bisogna smontare/espellere il disco virtuale creato dal DMG ed eliminare quest’ultimo in due passaggi separati. OS X non ci permette di fare la cosa contemporaneamente, poiché si tratta di due diversi tipi di elementi.

Alla lunga la cosa, per chi scarica frequentemente applicazioni da web, può irritare molto, per cui siamo andati a creare, grazie all’aiuto di Macworld, uno script in lingua italiana in grado di semplificarci la vita. Inoltre, ci abbiamo aggiunto qualche passaggio in più per rendere il tutto ancora più funzionale. Vediamo come fare:

Iniziamo aprendo Automator: si tratta di una applicazione complessa per l’utenza media, in grado di creare processi automatici personalizzati. Tranquilli: se leggerete attentamente queste righe non c’è pericolo di perdersi tra tutti i comandi disponibili. All’apertura ci verrà chiesto su cosa lavorare. Selezioniamo Servizi.

Puntate gli occhi sulla metà destra dell’applicazione: in alto, ci saranno dei parametri da sistemare in questo modo:

 Ok, adesso dall’elenco nella metà sinistra dell’applicazione dobbiamo trovare il comando Esegui Applescript. Potete aiutarvi tramite lo strumento di ricerca rapida. Una volta trovato, trascinatelo nel box vuoto a destra. Dovrebbe apparire così:

Nel box è già presente del testo. Cancelliamo tutto in modo da renderlo completamente vuoto. Successivamente, incolliamo questa serie di stringhe esattamente come ve la riportiamo qui:

tell application "Finder"
	set selection_list to selection
	if (count selection_list) < 1 then
		display dialog ¬
			"Per eseguire questo comando è necessario selezionare almeno un file .DMG" with title ¬
			"Nessuna selezione impostata" with icon stop ¬
			buttons ["OK"] default button 1
		return
	end if

	set my_selection to item 1 of selection_list
	set my_kind to kind of my_selection
	set my_name to name of my_selection

	if my_kind is not "Volume" then
		display dialog ¬
			"Questo comando è disponibile solo selezionando uno o più files .DMG" with title ¬
			"Nessun .DMG nella selezione" with icon stop ¬
			buttons ["OK"] default button 1
		return
	end if

	set volume_list to paragraphs of (do shell script "hdiutil info | grep ^/dev/disk | grep -o '/Volumes/.*'")
	set source_list to paragraphs of (do shell script "hdiutil info | grep ^image'-'alias | grep  -o '/.*'")

	set match_found to false
	repeat with v from 1 to (count volume_list)
		if "/Volumes/" & my_name = item v of volume_list then
			set match_found to true
			exit repeat
		end if
	end repeat

	if match_found is not equal to true then
		display dialog ¬
			"The selected volume does not appear to be a Disk Image." with title ¬
			"Could not find Disk Image" with icon stop ¬
			buttons ["OK"] default button 1
		return
	else
		set my_source to POSIX file (item v of source_list) as alias
		move my_source to the trash
		eject my_selection
		--reveal my_source
	end if
end tell

Finito questo, possiamo salvare il comando dirigendoci su File > Salva. Diamo un nome adeguato al servizio (ad esempio: smonta ed elimina DMG).

E adesso? Provate a selezionare un file immagine montato a partire da un .DMG. Se vi recate su Finder > Servizi, troverete il vostro “Smonta e cancella DMG” pronto per essere utilizzato. A dire il vero, dovreste essere in grado di lanciare il comando anche solo attraverso il menu richiamabile con il tasto destro ma, almeno su Mountain Lion, il comando non appare.

Ottimo no? Però ancora non siamo soddisfatti. Gli utenti più smaliziati sanno che per smontare i files immagine e i volumi si usa la combinazione da tastiera CMD+E. Vediamo di arricchirla con questo nuovo comando.

Entriamo nel Finder e soffermiamoci sulla barra menu in alto di OS X. Clicchiamo su Finder > Servizi > Preferenze Servizi. Da qui individuiamo il comando che abbiamo creato con Automator. Possiamo impostare, a partire da qui, una scorciatoia rapida, ad esempio CMD+SHIFT+E.

Premendo questa serie di tasti dopo aver selezionato una immagine disco di un DMG, quest’ultima verrà automaticamente smontata e il relativo DMG verrà eliminato. Così è davvero perfetto. Si tratterà pur sempre di una piccolezza, ma sarà indispensabile per gli utenti che provano molteplici applicazioni e si irritano nel voler eliminare in fretta i files di installazione.